#! /usr/bin/perl -w

# Check extensible command table of the UCD-SNMP-MIB.
# A table of extensible commands returning output and return codes.
# These commands are configured via the agent's snmpd.conf file.
#
# UCD SNMP MIB (1.3.6.1.4.1.2021).
# Used in net-snmp packages on linux.
#
# Copyright (C) 2007 by Herbert Stadler
# email: hestadler@gmx.at

# License Information:
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License 
# along with this program; if not, see <http://www.gnu.org/licenses/>. 
#
#

############################################################################


use POSIX;
use strict;
use Getopt::Long;

use lib ".";
use lib "/usr/lib/nagios/plugins";
use lib "/usr/lib64/nagios/plugins";
use lib "/usr/local/nagios/libexec";

use utils qw(%ERRORS);

use Net::SNMP qw(oid_lex_sort oid_base_match);

my ($opt_version,$opt_help,$opt_verbose);
my ($opt_timeout,$opt_license);
my ($opt_hostname,$opt_community,$opt_port,$opt_snmpvers);
my ($opt_username,$opt_authpasswd,$opt_authproto);
my ($opt_privpasswd,$opt_privproto);
my ($opt_extcmdname);
my ($PROGNAME,$REVISION);
my ($state,$msg);

use constant DEFAULT_TIMEOUT		=>15;
use constant DEFAULT_PORT    		=>161;
use constant DEFAULT_COMMUNITY  	=>"public";
use constant DEFAULT_SNMPVERS 		=>"2";
use constant DEFAULT_PRIVPROTO		=>"DES";
use constant DEFAULT_AUTHPROTO		=>"MD5";

#  UCD SNMP MIB 
my $extTable     			="1.3.6.1.4.1.2021.8";
my  $extEntry  				="1.3.6.1.4.1.2021.8.1";
my   $extIndex_tabular			="1.3.6.1.4.1.2021.8.1.1";
my   $extNames_tabular			="1.3.6.1.4.1.2021.8.1.2";
my   $extCommand_tabular		="1.3.6.1.4.1.2021.8.1.3";
my   $extResult_tabular			="1.3.6.1.4.1.2021.8.1.100";
my   $extOutput_tabular			="1.3.6.1.4.1.2021.8.1.101";


$ENV{'PATH'}='';
$ENV{'BASH_ENV'}=''; 
$ENV{'ENV'}='';
$PROGNAME = "check_extcmd_ucd";
$REVISION = "1.3";

# checking commandline arguments
my $arg_status = check_args();
if ($arg_status){
  print "ERROR: some arguments wrong\n";
  exit $ERRORS{"UNKNOWN"};
}

# set alarmhandler for timeout handling
$SIG{'ALRM'} = sub {
  print ("ERROR: plugin timed out after $opt_timeout seconds \n");
  exit $ERRORS{"UNKNOWN"};
};

alarm($opt_timeout);

# let's see if the server wants to speak with us
my ($snmp_session,$snmp_error)=open_snmp_session($opt_hostname);
if ( ! defined ($snmp_session)) {
  print "ERROR: Could not open connection: $snmp_error \n";
  exit $ERRORS{'UNKNOWN'};
}

$snmp_session->translate(['-endofmibview'=>0,'-nosuchobject'=>0,'-nosuchinstance'=>0]);

#  get extTable
my $p_extTable=get_table ($extTable);

$snmp_session->close;

if ( $opt_verbose ) {
  print_extTable ();
}

# default Message in case we don't find the command
my $l_tmsg = sprintf("Extensible Command %s not found",$opt_extcmdname);
$state = $ERRORS{'UNKNOWN'};

foreach my $l_key (oid_lex_sort(keys(%$p_extTable))){
  if (!(oid_base_match($extIndex_tabular,$l_key))) {
    next;
  }
  my $l_val=$p_extTable->{$l_key};
  if ( $p_extTable->{$extNames_tabular.".".$l_val} eq $opt_extcmdname ){
    $state = $p_extTable->{$extResult_tabular.".".$l_val};
    $l_tmsg=$p_extTable->{$extOutput_tabular.".".$l_val};
  }
}

if ($state == $ERRORS{'OK'}){
  $msg = $opt_extcmdname." OK - ".$l_tmsg;
} elsif ($state == $ERRORS{'WARNING'}){
  $msg = $opt_extcmdname." WARNING - ".$l_tmsg;
} elsif ($state == $ERRORS{'CRITICAL'}){
  $msg = $opt_extcmdname." CRITICAL - ".$l_tmsg;
} elsif ($state == $ERRORS{'UNKNOWN'}){
  $msg = $opt_extcmdname." UNKNOWN - ".$l_tmsg;
} else {
  $msg = $opt_extcmdname.sprintf(" UNKNOWN - Unknown RC, RC=%d",$state);
  $state = $ERRORS{'UNKNOWN'};
}

# and now "over and out"

print "$msg\n";
exit $state;




#--------------------------------------------------------------------------#
# S U B R O U T I N E S                                                    #
#--------------------------------------------------------------------------#

sub open_snmp_session {
  my ($l_host)=@_;

  my ($snmp_session,$snmp_error);

  # open SNMP Session to Server
  if ( $opt_snmpvers eq "3" ) {
    if ( defined ($opt_authpasswd)) {
      if ( defined ($opt_privpasswd)) {
	($snmp_session,$snmp_error)=Net::SNMP->session(
	    -hostname 		=> 	$l_host,
	    -port		=>	$opt_port || 161,
	    -timeout		=>	2,
	    -retries		=>	2,
	    -maxmsgsize		=>	16384,
	    -version		=>	$opt_snmpvers,
	    -username		=> 	$opt_username,
	    -authpassword	=> 	$opt_authpasswd,
	    -authprotocol	=> 	$opt_authproto,
	    -privpassword	=> 	$opt_privpasswd,
	    -privprotocol	=> 	$opt_privproto,
	    );
      } else {
	($snmp_session,$snmp_error)=Net::SNMP->session(
	    -hostname 		=> 	$l_host,
	    -port		=>	$opt_port || 161,
	    -timeout		=>	2,
	    -retries		=>	2,
	    -maxmsgsize		=>	16384,
	    -version		=>	$opt_snmpvers,
	    -username		=> 	$opt_username,
	    -authpassword	=> 	$opt_authpasswd,
	    -authprotocol	=> 	$opt_authproto,
	    );
      } 
    } else {
	($snmp_session,$snmp_error)=Net::SNMP->session(
	    -hostname 		=> 	$l_host,
	    -port		=>	$opt_port || 161,
	    -timeout		=>	2,
	    -retries		=>	2,
	    -maxmsgsize		=>	16384,
	    -version		=>	$opt_snmpvers,
	    -username		=> 	$opt_username,
	    );
    }
  } else {
    ($snmp_session,$snmp_error)=Net::SNMP->session(
    	-hostname 	=> 	$l_host,
	-community 	=> 	$opt_community || 'public',
	-port		=>	$opt_port || 161,
	-timeout	=>	2,
	-retries	=>	2,
	-maxmsgsize	=>	16384,
	-version	=>	$opt_snmpvers,
	);
  }
  return ($snmp_session,$snmp_error);
}

sub get_table {
  my ($l_oid)=@_;

  my $l_snmp_result=$snmp_session->get_table(
  	-baseoid 	=>	$l_oid
  	);

  #if ( ! defined ($l_snmp_result)) {
  if ($snmp_session->error_status != 0) {
    print "ERROR %d: get_table: ",$snmp_session->error_status,$snmp_session->error,"\n";
    $snmp_session->close;
    exit $ERRORS{'UNKNOWN'};
  }
  return $l_snmp_result;
}

sub check_args {
  Getopt::Long::Configure('bundling');
  GetOptions
	("V"   			=> \$opt_version,
	 "version"   		=> \$opt_version,
	 "L"   			=> \$opt_license, 
	 "license"   		=> \$opt_license, 
	 "v"   			=> \$opt_verbose, 
	 "verbose"   		=> \$opt_verbose, 
	 "h|?" 			=> \$opt_help,
	 "help"   		=> \$opt_help,
	 "t=i" 			=> \$opt_timeout, 
	 "timeout=i" 		=> \$opt_timeout, 
	 "H=s" 			=> \$opt_hostname, 
	 "hostname=s" 		=> \$opt_hostname, 
	 "C=s" 			=> \$opt_community, 
	 "community=s" 		=> \$opt_community, 
	 "p=i" 			=> \$opt_port, 
	 "port=i" 		=> \$opt_port, 
	 "s=s" 			=> \$opt_snmpvers, 
	 "snmpvers=s" 		=> \$opt_snmpvers, 
         "u=s"       		=> \$opt_username,
         "username=s"       	=> \$opt_username,
         "o=s"   		=> \$opt_authpasswd,
         "authpass=s"   	=> \$opt_authpasswd,
         "r=s"   		=> \$opt_authproto,
         "authprot=s"   	=> \$opt_authproto,
         "O=s"   		=> \$opt_privpasswd,
         "privpass=s"   	=> \$opt_privpasswd,
         "R=s"   		=> \$opt_privproto,
         "privprot=s"   	=> \$opt_privproto,
         "E=s"   		=> \$opt_extcmdname,
         "extcmd=s"   		=> \$opt_extcmdname,
	 );

  if ($opt_license) {
    print_gpl($PROGNAME,$REVISION);
    exit $ERRORS{'OK'};
  }

  if ($opt_version) {
    print_revision($PROGNAME,$REVISION);
    exit $ERRORS{'OK'};
  }

  if ($opt_help) {
    print_help();
    exit $ERRORS{'OK'};
  }

  if ( ! defined($opt_hostname)){
    print "\nERROR: Hostname not defined\n\n";
    print_usage();
    exit $ERRORS{'UNKNOWN'};
  }

  unless (defined $opt_snmpvers) {
    $opt_snmpvers = DEFAULT_SNMPVERS;
  }
  if (($opt_snmpvers ne "1") && ($opt_snmpvers ne "2") && ($opt_snmpvers ne "3")) {
    printf ("\nERROR: SNMP Version %s unknown\n",$opt_snmpvers);
    print_usage();
    exit $ERRORS{'UNKNOWN'};
  }

  unless (defined $opt_timeout) {
    $opt_timeout = DEFAULT_TIMEOUT;
  }

  unless (defined $opt_port) {
    $opt_port = DEFAULT_PORT;
  }

  unless (defined $opt_community) {
    $opt_community = DEFAULT_COMMUNITY;
  }

  if (defined $opt_privpasswd) {
    unless (defined $opt_privproto) {
      $opt_privproto = DEFAULT_PRIVPROTO;
    }
  }

  if (defined $opt_authpasswd) {
    unless (defined $opt_authproto) {
      $opt_authproto = DEFAULT_AUTHPROTO;
    }
  }

  if ($opt_snmpvers eq 3) {
    unless (defined $opt_username) {
      printf ("\nERROR: SNMP Version %s: please define username\n",$opt_snmpvers);
      print_usage();
      exit $ERRORS{'UNKNOWN'};
    }
  }

  unless (defined $opt_extcmdname) {
    printf ("\nERROR: extensible command name not defined\n");
    print_usage();
    exit $ERRORS{'UNKNOWN'};
  }

  return $ERRORS{'OK'};
}

sub print_usage {
  print "Usage: $PROGNAME [-h] [-L] [-t timeout] [-v] [-V] [-C community] [-p port] [-s 1|2|3] -H hostname -E extcmd \n\n";
  print "SNMP version 3 specific: [-u username] [-o authpass] [-r authprot] [-O privpass] [-R privprot]\n";
}

sub print_help {
  print_revision($PROGNAME,$REVISION);
  print "\n";
  print_usage();
  print "\n";
  print "   Check extensible command table of the UCD-SNMP-MIB.\n";
  print "   A table of extensible commands returning output and return codes.\n";
  print "   These commands are configured via the agent's snmpd.conf file.\n";
  print "   e.g: used on linux in net-snmp agent.\n\n";
  print "-t (--timeout)      Timeout in seconds (default=",DEFAULT_TIMEOUT,")\n";
  print "-H (--hostname)     Host to monitor\n";
  print "-E (--extcmd)       extensible command name\n";
  print "-s (--snmpvers)     SNMP Version [1|2|3] (default=",DEFAULT_SNMPVERS,")\n";
  print "-C (--community)    SNMP Community (default=",DEFAULT_COMMUNITY,")\n";
  print "-p (--port)         SNMP Port (default=",DEFAULT_PORT,")\n";
  print "-h (--help)         Help\n";
  print "-V (--version)      Programm version\n";
  print "-v (--verbose)      Print some useful information\n";
  print "-L (--license)      Print license information\n";
  print "\nSNMP version 3 specific arguments:\n";
  print "-u (--username)     Security Name\n";
  print "-o (--authpassword) Authentication password\n";
  print "-r (--authprotocol) Authentication protocol [md5|sha]\n";
  print "-O (--privpassword) Privacy password\n";
  print "-R (--privprotocol) Privacy protocol [des|aes|3des]\n";
  print "\n";
}

sub print_extTable {
  printtable  ("UCD Extensible Command Table");
  print       ("============================\n");
  foreach my $l_key (oid_lex_sort(keys(%$p_extTable))){
    if (!(oid_base_match($extIndex_tabular,$l_key))) {
      next;
    }
    my $l_val=$p_extTable->{$l_key};
    printtabular("Names",    $p_extTable->{$extNames_tabular.".".$l_val});
    printtabular("Command",  $p_extTable->{$extCommand_tabular.".".$l_val});
    printtabular("Result",   $p_extTable->{$extResult_tabular.".".$l_val});
    printtabular("Output",   $p_extTable->{$extOutput_tabular.".".$l_val});
    print ("\n");
  }
}

sub printhead {
  my ($l_head)=@_;

  printf ("\n%-40s\n",$l_head);
}

sub printtable {
  my ($l_head)=@_;

  printf ("%-40s\n",$l_head);
}

sub printscalar {
  my ($l_arg,$l_oid)=@_;

  printf ("%-35s: %-30s\n",$l_arg,$l_oid);
}

sub printtabular {
  my ($l_arg,$l_oid)=@_;

  printf ("%-35s: %-30s\n",$l_arg,$l_oid);
}


sub print_gpl {
  print <<EOD;

  Copyright (C) 2007 by Herbert Stadler
  email: hestadler\@gmx.at

  License Information:
  This program is free software; you can redistribute it and/or modify
  it under the terms of the GNU General Public License as published by
  the Free Software Foundation; either version 3 of the License, or
  (at your option) any later version.
 
  This program is distributed in the hope that it will be useful,
  but WITHOUT ANY WARRANTY; without even the implied warranty of
  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  GNU General Public License for more details.
 
  You should have received a copy of the GNU General Public License 
  along with this program; if not, see <http://www.gnu.org/licenses/>. 

EOD

}

sub print_revision {
  my ($l_prog,$l_revision)=@_;

  print <<EOD

$l_prog $l_revision, Copyright (C) 2007 Herbert Stadler

This program comes with ABSOLUTELY NO WARRANTY; 
for details type "$l_prog -L".
EOD
}


#__END__


=head1 NAME

 check_extcmd_ucd

=head1 DESCRIPTION

 Check extensible command table of the UCD-SNMP-MIB.
 A table of extensible commands returning output and return codes.
 These commands are configured via the agent's snmpd.conf file.
 e.g: used on linux in net-snmp agent

 Plugin created for Nagios Monitoring.

=head1 SYNOPSIS

 check_extcmd_ucd -H <hostname> -E <extcmdname> 

 for more information concerning this plugin call:
     check_extcmd_ucd -h
     perldoc check_extcmd_ucd

 more information concerning the configuration of the UCD SNMP Package:
     man snmpd.conf

 The extensible command should return the same return codes as Nagios does
 (0=OK, 1=WARNING, 2=CRITICAL, 3=UNKNOWN).

=head1 AUTHOR

 Herbert Stadler, Austria (hestadler@gmx.at)
 December 2007

 This plugin is a contribution to the nagios community.

=head1 REQUIRED SOFTWARE

 from search.cpan.org
   Net::SNMP Package   	e.g: Net-SNMP-5.2.0.tar.gz

=head1 HOW TO CHECK THE SERVER FUNCTIONALITY

 Example:
   snmpwalk 172.29.130.201 -v2c -c public enterprises.2021.8

 should return some lines like these:

  UCD-SNMP-MIB::extIndex.1 = INTEGER: 1
  UCD-SNMP-MIB::extIndex.2 = INTEGER: 2
  UCD-SNMP-MIB::extNames.1 = STRING: testcmd1
  UCD-SNMP-MIB::extNames.2 = STRING: testcmd2
  UCD-SNMP-MIB::extCommand.1 = STRING: /root/test1.bash
  UCD-SNMP-MIB::extCommand.2 = STRING: /root/test2.bash
  UCD-SNMP-MIB::extResult.1 = INTEGER: 0
  UCD-SNMP-MIB::extResult.2 = INTEGER: 2
  UCD-SNMP-MIB::extOutput.1 = STRING: no errors found
  UCD-SNMP-MIB::extOutput.2 = STRING: please check log
  UCD-SNMP-MIB::extErrFix.1 = INTEGER: 0
  UCD-SNMP-MIB::extErrFix.2 = INTEGER: 0
  UCD-SNMP-MIB::extErrFixCmd.1 = STRING: 
  UCD-SNMP-MIB::extErrFixCmd.2 = STRING: 

 if not, check the configuration file 
   - on linux (/etc/snmp/snmpd.conf)
	# Executables/scripts (Examples)
        #    NAME     PROGRAM   ARGS
	exec echotest /bin/echo hello world

=head1 CONFIGURATION IN NAGIOS

 Copy this plugin to the nagios plugin installation directory 
 e.g.: /usr/lib(64)/nagios/plugin

 COMMAND DEFINITION:

 # "check_extcmd_ucd" command definition
 define command{
    command_name    check_extcmd_ucd
    command_line    $USER1$/check_extcmd_ucd -H $HOSTADDRESS$
    }


=head1 PLUGIN HISTORY

 Version 1.0 - 2007-12-15	first release
 Version 1.1 - 2007-12-19       fixed problem with **ePN
                                (Missing right curly or square ...)
 Version 1.2 - 2009-02-17       some new "use lib .." statements
 Version 1.3 - 2010-03-24       check error_status of snmp call

=head1 COPYRIGHT AND DISCLAIMER

 Copyright (C) 2007 by Herbert Stadler
 email: hestadler@gmx.at

 License Information:
 This program is free software; you can redistribute it and/or modify
 it under the terms of the GNU General Public License as published by
 the Free Software Foundation; either version 3 of the License, or
 (at your option) any later version.
 
 This program is distributed in the hope that it will be useful,
 but WITHOUT ANY WARRANTY; without even the implied warranty of
 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 GNU General Public License for more details.
 
 You should have received a copy of the GNU General Public License 
 along with this program; if not, see <http://www.gnu.org/licenses/>. 
 

=cut